gfun[listtorec] - find a recurrence for the elements

gfun[seriestorec] - find a recurrence for the coefficients of a series

Calling Sequence

listtorec(l, u(n), <[typelist]>, <operator=op>)

seriestorec(s, u(n), <[typelist]>, <operator=op>)

Parameters

l - a list

s - a series

u(n) - the unknown function and its variable

[typelist] - (optional) a list of generating function types

operator=op - (optional) output form, where op is equation or a name

Description

The procedures listtorec and seriestorec compute a linear recurrence with polynomial coefficients satisfied by the expressions in l or s, with a normalization specified by typelist, for example ordinary (ogf) or exponential (egf). For a full list of available choices see gftypes.
If typelist contains more than one element, these types are tried in order.
If typelist is not provided, the default optionsgf, initially ['ogf'], is used. Without an explicit typelist or optionsgf option, the output is the recurrence with its initial conditions. When a type list is supplied, the output is tagged with the type for which a recurrence was found.
The default operator=equation returns the recurrence and its initial conditions. If operator is set to a name, for example operator=Sn, the result is instead a polynomial in Sn, representing the recurrence operator obtained by replacing each shift u(n+i) by Sn^i. Initial conditions are omitted from this form. If a generating function type was explicitly supplied, the operator polynomial is tagged with that type.
The search is controlled by the options minordereqn, maxordereqn, maxdegcoeffs, checkterms, mode, and modulo. For more information on these options, see gfun[parameters].
One should give as many terms as possible in the list l or the series s.
The option homogeneous=bool selects whether listtorec and seriestorec search for a homogeneous or inhomogeneous recurrence. The default is true. With homogeneous=false, the constant sequence is included directly in the Hermite-Pade problem.
When a named shift operator is requested together with homogeneous=false, the operator form is returned as an equation L=-q.

Examples

> with(gfun):
l:=[1, 1, 2, 5, 14, 42, 132, 429, 1430, 4862, 16796, 58786]:
rec:=listtorec(l,u(n));

\[\{\left(-4 n -2\right) u \! \left(n \right)+\left(n +2\right) u \! \left(n +1\right), u \! \left(0\right) = 1\}\]

> rsolve(op(1,rec),u(n));

\[\frac{4^{n} \Gamma \! \left(n +\frac{1}{2}\right) u \! \left(0\right)}{\sqrt{\pi}\, \Gamma \! \left(n +2\right)}\]

> rec2:=seriestorec(series(add(l[i]*x^(i-1)*(i-1)!, i=1..nops(l))+O(x^nops(l)),x, 12), u(n), ['egf']);

\[[\{\left(-4 n -2\right) u \! \left(n \right)+\left(n +2\right) u \! \left(n +1\right), u \! \left(0\right) = 1\}, \mathit{egf}]\]

> listtorec(l,u(n),operator=Sn);

\[-4 n -2+\left(n +2\right) \mathit{Sn}\]